New Field for storing Feeding date

Add a new field in voucher for storing feeding date which is invisible and in Day book user can filter the data for feeding date which is assign with a Button which is active only to Owner

;;---------------- UDFs----------------------------------

[System : UDF]
UDF_RBPLFeedDate : Date: 8000

;;---------------- Voucher Level Changes ----------------

[#Field: VCH Date]
Add : Fields: Before: Plain VCH Date : _FeedDate_Fld

[Field :_FeedDate_Fld]
Use : Uni Date Field
Set as : $$MachineDate
Storage : UDF_RBPLFeedDate
width : @@VCHDateWidth
Type : Date : Forced
SetAlways : Yes
Invisible : Yes ;;$$CmpUserLevel Not = "Owner"

;;---------------- Report Level Changes ----------------

[#Line: DSP VchDetail]
Add : Fields: Before: DSP VchDate : Dsp_FeedDate_Fld

[Field: Dsp_FeedDate_Fld]

Use : Short Date Field
Set as : $UDF_RBPLFeedDate
Style : Normal
Align : Right
Invisible : $$CmpUserLevel Not = "Owner"

;;---------------- Filteration level Changes ----------------
[#Form: Day Book]
Add : Button : MyDateFltBtn

[Button : MyDateFltBtn]
Action : Execute : MyDateFltRep
Title : $$LocaleString:"Feed Date"
Key : Alt + F3
InActive : $$CmpUserLevel Not = "Owner"

[Report : MyDateFltRep]
Form : MyDateFltFrm
Title : $$LocaleString:"Feed Date Period"

[Form : MyDateFltFrm]
Part : MyDateFltPrt

[Part : MyDateFltPrt]
Line : MyDateFltLn1, MyDateFltLn2

[Line : MyDateFltLn1]
Field : Short Prompt, DtEntered1
Local : Field : Short PRompt : Info : "From Date :"

[Field : DtEntered1]
Use : Short Date Field
Variable : MyDateTypeVari1
Modifies : MyDateTypeVari1
Set Always : No

[Line : MyDateFltLn2]
Field : Short Prompt, DtEntered2
Local : Field : Short PRompt : Info : "To Date :"

[Field : DtEntered2]
Use : Short Date Field
Variable : MyDateTypeVari2
Modifies : MyDateTypeVari2
Set Always : No

[Variable : MyDateTypeVari1]
Type : Date
Persistent : No

[Variable : MyDateTypeVari2]
Type : Date
Persistent : No


[#Collection : Vouchers of Company]

Add : Filter : FeedDateFilter

[System : Formula]

FeedDateFilter : If $$IsEmpty:##MyDateTypeVari1 Then +
$UDF_RBPLFeedDate >= ##MyDateTypeVari1 +
Else +
$UDF_RBPLFeedDate >= ##MyDateTypeVari1 AND $UDF_RBPLFeedDate <= ##MyDateTypeVari2

[System : Variable]

MyDateTypeVari1 : $$Date
MyDateTypeVari2 : $$Date